ネット非対応のテレビドアホンでネット通知したい

#include <WiFi.h>              //Wi-Fi
#include <WiFiClientSecure.h>  //Wi-Fi
#include <ArduinoJson.h>

#define A_SW 25             //ドアホンA接点
#define LED_BUILTIN 2       //内蔵LED

#define JST 3600 * 9
#define PUSH_SHORT 50     // チャタリング防止用時間(ms). 50-100で調整

// --- Slack Webhook 設定 ---
const char* slackHost = "hooks.slack.com";
const char* slackPath = "/services/XXXXXXXXX/XXXXXXXXXXX/xxxxxxxxxxxxxxxxxxxxxxxx";

// WiFi設定
const char* ssid = "your SSID";
const char* password = "your PASSWORD";
String hostname = "INTPHONE";

bool done = true;

RTC_DATA_ATTR int bootCount = 0;
unsigned long lastRestart = 0;

//----------------------------------
// デバウンス用構造体
//----------------------------------
struct Debounce {
  uint8_t pin;
  int lastStable;           // 最後に確定した安定状態 (HIGH/LOW)
  unsigned long lastChange; // millis() を記録
  bool reported;            // その LOW 確定を報告済みか (立下がりを一度だけ返すため)
};

Debounce dbA = { A_SW, HIGH, 0UL, false };

//----------------------------------
// デバウンス検出関数（立下がりを1回だけtrueで返す）
// 使い方: if (debounceFalling(&dbA)) { ... }
//----------------------------------
bool debounceFalling(Debounce *db) {
  int reading = digitalRead(db->pin);

  if (reading != db->lastStable) {
    // 状態が変化した（暫定） -> タイマーをリセット
    db->lastChange = millis();
    db->lastStable = reading; // update the last observed level for timing
    db->reported = false;     // 未報告に戻す
    return false;
  } else {
    // 状態が変わらない -> 経過時間が閾値を超えたら確定
    if ((millis() - db->lastChange) > PUSH_SHORT) {
      // LOWが確定していて、まだ報告していなければ立下がりを返す
      if (reading == LOW && db->reported == false) {
        db->reported = true;  // 1回だけ報告する
        return true;
      }
    }
  }
  return false;
}

// ドアホン用（3回繰り返し）
void interphoneCall() {
  Serial.println("ドアホン呼出検知");
}

//----------------------------------
void setup() {
  Serial.begin(115200);
  lastRestart = millis();

  pinMode(A_SW, INPUT_PULLUP);    //ドアホンA接点短絡でON
  pinMode(LED_BUILTIN, OUTPUT);   //LED
  digitalWrite(LED_BUILTIN, LOW);//LED初期状態OFF

  // WiFi接続
  WiFi.disconnect(true, true);
  WiFi.mode(WIFI_STA);
  WiFi.setHostname(hostname.c_str());
  WiFi.begin(ssid, password);
  while (done) {
    Serial.print("Wi-Fi connecting");
    auto last = millis();
    while (WiFi.status() != WL_CONNECTED && last + 5000 > millis()) {
      delay(500);
      Serial.print(".");
    }
    if (WiFi.status() == WL_CONNECTED) {
      done = false;
    } else {
      Serial.println("Retry");
      WiFi.disconnect(true, true);
      //WiFi.reconnect();
      ESP.restart();
    }
  }
  Serial.println("Wi-Fi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  configTime(JST, 0, "pool.ntp.org", "jp.pool.ntp.org");

  delay(5000);
  sendSlackMessage("🤖 起動OK!");
  Serial.println("起動OK!");
}

// Slack にメッセージを送信する関数
void sendSlackMessage(const char* message) {
  WiFiClientSecure client;
  client.setInsecure(); // 簡易的に証明書検証を無効化

  if (!client.connect(slackHost, 443)) {
    Serial.println("Slack connection failed");
    return;
  }

  String payload = String("{\"text\":\"") + message + "\"}";

  String request = String("POST ") + slackPath + " HTTP/1.1\r\n" +
                   "Host: " + slackHost + "\r\n" +
                   "Content-Type: application/json\r\n" +
                   "Content-Length: " + payload.length() + "\r\n\r\n" +
                   payload;

  client.print(request);

  // レスポンスを読み出して確認
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") break; // ヘッダ終了
    Serial.println(line);    // デバッグ出力
  }
  String response = client.readString();
  Serial.println("Response: " + response);
}

//----------------------------------
void loop() {

  ///////////////////////
  time_t t;
  struct tm* tm;
  static const char* wd[7] = { "Sun", "Mon", "Tue", "Wed", "Thr", "Fri", "Sat" };
  t = time(NULL);
  tm = localtime(&t);

  char timeStr[16];
  sprintf(timeStr,"%02d:%02d:%02d",tm->tm_hour, tm->tm_min, tm->tm_sec);

  // 毎日06:05にRestart(ハングアップ対策)
  if ((tm->tm_hour == 06) && (tm->tm_min == 05) && (tm->tm_sec == 00)) {
    ESP.restart();
  }

  // ドアホン呼出 (立下がり検出)
  if (debounceFalling(&dbA)) {
    interphoneCall();
    sendSlackMessage(String("🚪 おや?誰か来たようだ! (" + String(timeStr) + ")").c_str());
  }
}